VB .NET - Obtendo informações das interfaces de rede local (II)

Você esta precisando obter informações sobre as interfaces das redes locais no seu computador ?

Não se perturbe, o VB .NET possui recursos que facilitam obter essas informações.

Para obter informações das redes locais chame o método estático(Shared) GetAllNetworkInterfaces do namespace System.Net.NetworkInformation.NetworkInterface para obter uma matriz de objetos derivados da classe abstrata NetworkInterface.

Cada objeto representa uma interface de rede disponível na máquina local. A seguir você pode usar os membros de cada objeto NetworkInterface para recuperar informações de configuração e estatísticas de rede para essa interface.

O namespace System.Net.NetworkInformation , que foi introduzido pela primeira vez em .NET Framework 2.0, fornece acesso fácil às informações sobre a configuração da rede e estatísticas que antes não eram disponíveis.

O principal meio de recuperar informações de rede são as propriedades e métodos da classe NetworkInterface . Você não instancia os objetos NetworkInterface diretamente. Em vez disso, você chama o método estático NetworkInterface.GetAllNetworkInterfaces que retorna um array de objetos NetworkInterface .

Cada objeto representa uma única interface de rede na máquina local; você pode, então, obter informações sobre a rede e as estatísticas da interface usando os membros da interface NetworkInterface.

Abaixo temos um resumo dos principais métodos e propriedades:

Propriedades:

Métodos:

Vamos criar um projeto bem simples para obter informações das interfaces das redes locais usando os recursos acima.

Abra o Visual Studio 2012 Express for desktop e clique no menu File -> New Project selecionando o template Visual Basic -> Windows Forms Application informando o nome VB_Informacoes_Rede.

A seguir inclua os seguintes controles no formulário form1.vb:

• ListBox - name = lbInfo
• Button - name = btnInfo

Disponha os controles conforme a figura abaixo:

No início do formulário form1.vb declare o seguinte namespace:

Imports System.Net.NetworkInformation

A seguir no evento Click do botão de comando inclua o código abaixo:

Private Sub btnInfo_Click(sender As Object, e As EventArgs) Handles btnInfo.Click
        ' Somente continua se existir uma rede disponível
        If NetworkInterface.GetIsNetworkAvailable Then
            ' Obtém e define todos os objetos NetworkInterface para a máquina local
            Dim interfaces As NetworkInterface() = NetworkInterface.GetAllNetworkInterfaces()
            ' Itera sobre as interfaces e exibe as informações
            For Each ni As NetworkInterface In interfaces
                ' Rela a informação da interface
                lbInfo.Items.Add("Interface: " &  ni.Name)
                lbInfo.Items.Add(" Descrição: " &  ni.Description)
                lbInfo.Items.Add(" ID: " &  ni.Id)
                lbInfo.Items.Add(" Tipo: " &  ni.NetworkInterfaceType)
                lbInfo.Items.Add(" Velocidade: " &  ni.Speed)
                lbInfo.Items.Add(" Status: " &  ni.OperationalStatus)
                ' endereço físico
                lbInfo.Items.Add(" Endereço Físico: " &  ni.GetPhysicalAddress().ToString)
                ' relata estatísticas de rede para a interface
                lbInfo.Items.Add(" Bytes Enviados : " &  ni.GetIPv4Statistics().BytesSent)
                lbInfo.Items.Add(" Bytes Recebidos: " &  ni.GetIPv4Statistics.BytesReceived)
                ' Configuração do IP
                lbInfo.Items.Add(" Endereço(s) IP : ")
                For Each addr As UnicastIPAddressInformation In ni.GetIPProperties.UnicastAddresses()
                    lbInfo.Items.Add(" - > " &  addr.Address.ToString & " - " & DateTime.Now.AddSeconds(addr.DhcpLeaseLifetime))
                Next
                lbInfo.Items.Add(Environment.NewLine)
            Next
        Else
            lbInfo.Items.Add("Nenhuma interface de rede localizada.")
        End If
        lbInfo.Items.Add(Environment.NewLine)
        lbInfo.Items.Add("Operação concluída.")
    End Sub

Executando o projeto e clicando no botão de comando obtemos o seguinte resultado:

Simples e funcional.

Pegue o projeto completo aqui: VB_Informacoes_Rede.zip

   Gostou ?   Compartilhe no Facebook    Compartilhe no Twitter

Referências:

• Seção VB - Prático do site Macoratti .net
• Seção VB .NET do Site Macoratti.net
• Super DVD .NET - A sua porta de entrada na plataforma .NET
• Super DVD Vídeo Aulas - Vídeo Aula sobre VB .NET, ASP .NET e C#
• Seção C# do site Macoratti.net

José Carlos Macoratti