Neste artigo eu vou mostrar como podemos exibir imagens e texto em uma célula do controle DataGridView em uma aplicação Windows Forms usando a linguagem VB .NET.

 Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Try
            'define a string de conexão com o banco de dados Northwind
            Dim strConn As String = "Data Source=MAC\SQLEXPRESS;Initial Catalog=Northwind;Integrated Security=True"
            Dim conn As New SqlConnection(strConn)
            'define  a instrução SQL para selecionar registros da tabela Products
            Dim sql As String = "Select ProductID, ProductName, UnitPrice, UnitsInStock from Products"
            conn.Open()
            'define o dataadatper
            Dim da As New SqlDataAdapter(sql, conn)
            'cria o datatable
            dt = New DataTable
            'preeenche o datatable
            da.Fill(dt)
            'define o bindingsource com o datatable
            bs.DataSource = dt.DefaultView
            DataGridView1.DataSource = bs
            'remove a coluna ProductID
            DataGridView1.Columns.Remove("ProductID")
            'cria uma instância da classe TextAdnImagemCOlumn
            Dim dc As New TextAndImageColumn
            'define as propriedades da nova coluna
            dc.DataPropertyName = "ProductID"
            dc.HeaderText = "ID"
            'atribui uma imagem a coluna
            dc.Image = Image.FromFile("C:\Dados\Image1.jpg")
            DataGridView1.Columns.Insert(0, dc)
            ' altera a imagem para a segunda linha
            DirectCast(DataGridView1.Item(0, 1), TextAndImageCell).Image = Image.FromFile("C:\Dados\Image2.jpg")
            ' altera a imagem para a terceira linha
            DirectCast(DataGridView1.Item(0, 2), TextAndImageCell).Image = Image.FromFile("C:\Dados\Image3.jpg")
            ' altera a imagem para a quarta linha
            DirectCast(DataGridView1.Item(0, 3), TextAndImageCell).Image = Image.FromFile("C:\Dados\Image4.jpg")
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
    End Sub

  Public Class TextAndImageColumn
        Inherits DataGridViewTextBoxColumn

        Private imageValue As Image
        Private m_imageSize As Size

        Public Sub New()
            Me.CellTemplate = New TextAndImageCell
        End Sub

        Public Overloads Overrides Function Clone() As Object
            Dim c As TextAndImageColumn = TryCast(MyBase.Clone, TextAndImageColumn)
            c.imageValue = Me.imageValue
            c.m_imageSize = Me.m_imageSize
            Return c
        End Function

        Public Property Image() As Image
            Get
                Return Me.imageValue
            End Get
            Set(ByVal value As Image)
                Me.imageValue = value
                Me.m_imageSize = value.Size
                Dim inheritedPadding As Padding = Me.DefaultCellStyle.Padding
                Me.DefaultCellStyle.Padding = New Padding(ImageSize.Width, inheritedPadding.Top, inheritedPadding.Right, inheritedPadding.Bottom)
            End Set
        End Property

        Private ReadOnly Property TextAndImageCellTemplate() As TextAndImageCell
            Get
                Return TryCast(Me.CellTemplate, TextAndImageCell)
            End Get
        End Property
        Friend ReadOnly Property ImageSize() As Size
            Get
                Return m_imageSize
            End Get
        End Property
    End Class

 Public Class TextAndImageCell
        Inherits DataGridViewTextBoxCell

        Private imageValue As Image
        Private imageSize As Size

        Public Overloads Overrides Function Clone() As Object
            Dim c As TextAndImageCell = TryCast(MyBase.Clone, TextAndImageCell)
            c.imageValue = Me.imageValue
            c.imageSize = Me.imageSize
            Return c
        End Function

        Public Property Image() As Image
            Get
                If Me.OwningColumn Is Nothing OrElse Me.OwningTextAndImageColumn Is Nothing Then
                    Return imageValue
                Else
                    If Not (Me.imageValue Is Nothing) Then
                        Return Me.imageValue
                    Else
                        Return Me.OwningTextAndImageColumn.Image
                    End If
                End If
            End Get
            Set(ByVal value As Image)
                Me.imageValue = value
                Me.imageSize = value.Size
                Dim inheritedPadding As Padding = Me.InheritedStyle.Padding
                Me.Style.Padding = New Padding(imageSize.Width, inheritedPadding.Top, inheritedPadding.Right, inheritedPadding.Bottom)
            End Set
        End Property

        Protected Overloads Overrides Sub Paint(graphics As Graphics, clipBounds As Rectangle, cellBounds As Rectangle,
                                                rowIndex As Integer, cellState As DataGridViewElementStates, value As Object, formattedValue As Object,
                                                errorText As String, cellStyle As DataGridViewCellStyle, advancedBorderStyle As DataGridViewAdvancedBorderStyle,
                                                paintParts As DataGridViewPaintParts)

            MyBase.Paint(graphics, clipBounds, cellBounds, rowIndex, cellState, value, formattedValue, errorText, cellStyle, advancedBorderStyle, paintParts)

            If Not (Me.Image Is Nothing) Then
                Dim container As System.Drawing.Drawing2D.GraphicsContainer = graphics.BeginContainer
                graphics.SetClip(cellBounds)
                graphics.DrawImageUnscaled(Me.Image, cellBounds.Location)
                graphics.EndContainer(container)
            End If

        End Sub

        Private ReadOnly Property OwningTextAndImageColumn() As TextAndImageColumn
            Get
                Return TryCast(Me.OwningColumn, TextAndImageColumn)
            End Get
        End Property

    End Class

Quer migrar para o VB .NET ?

• Veja mais sistemas completos para a plataforma .NET no Super DVD .NET , confira...

• Curso Básico VB .NET - Vídeo Aulas

Quer aprender C# ??

• Chegou o Super DVD C# com exclusivo material de suporte e vídeo aulas com curso básico sobre C#.

• Curso C# Basico - Video Aulas

Quer aprender os conceitos da Programação Orientada a objetos ?

• Curso Fundamentos da Programação Orientada a Objetos com VB .NET

Quer aprender o gerar relatórios com o ReportViewer no VS 2013 ?

•  Curso - Gerando Relatórios com o ReportViewer no VS 2013 - Vídeo Aulas