Hoje eu volto ao assunto de como gerar documentos PDF usando a linguagem VB .NET. Neste artigo eu vou mostrar como gerar arquivos PDFs a partir de arquivos texto usando o PDFSharp.

Private Sub btnProcurar_Click(sender As Object, e As EventArgs) Handles btnProcurar.Click

        Dim ofd1 As OpenFileDialog = New OpenFileDialog
        'define as propriedades do controle OpenFileDialog
        ofd1.Multiselect = False
        ofd1.Title = "Selecionar Arquivo "
        ofd1.InitialDirectory = "C:\Dados\"
        'filtra para exibir somente arquivos textos
        ofd1.Filter = "Texto (*.TXT)|*.TXT;|" + "Todos (*.*)|*.*"
        ofd1.CheckFileExists = True
        ofd1.CheckPathExists = True
        ofd1.FilterIndex = 1
        ofd1.RestoreDirectory = True
        ofd1.ReadOnlyChecked = True
        ofd1.ShowReadOnly = False

        Dim dr As DialogResult = ofd1.ShowDialog()
        If dr = System.Windows.Forms.DialogResult.OK Then
            Try
                ' Le o arquivo selecionado
                txtArquivoTexto.Text = ofd1.FileName
            Catch ex As SecurityException
                ' O usuário  não possui permissão para ler arquivos
                MessageBox.Show("Erro de segurança Contate o administrador de segurança da rede." & vbLf & vbLf + "Mensagem : " 
+ ex.Message + vbLf & vbLf + "Detalhes (enviar ao suporte):" & vbLf & vbLf + ex.StackTrace)
            Catch ex As Exception
                ' Não pode carregar a imagem (problemas de permissão)
                MessageBox.Show("Você pode não ter permissão para ler o arquivo , ou " + " ele pode estar corrompido." & vbLf & 
vbLf & "Erro reportado : " + ex.Message)
            End Try
        End If
    End Sub

 Private Sub btnProcurarPasta_Click(sender As Object, e As EventArgs) Handles btnProcurarPasta.Click
        Dim fbd1 As FolderBrowserDialog = New FolderBrowserDialog
        If fbd1.ShowDialog = Windows.Forms.DialogResult.OK Then
            txtDestino.Text = fbd1.SelectedPath
        End If
End Sub

Private Sub btnGerarPDF_Click(sender As Object, e As EventArgs) Handles btnGerarPDF.Click

        Try
            'verifica se o arquivo texto e o destino foram informadaos
            If Not String.IsNullOrEmpty(txtArquivoTexto.Text) And Not String.IsNullOrEmpty(txtDestino.Text) Then
                'verifica se a pasta de destino existe
                If Directory.Exists(txtDestino.Text) Then
                    'define um linha e ponto e le o arquivo texto
                    Dim linha As String
                    Dim yPonto As Integer = 0
                    Dim arquivoTexto As TextReader = New StreamReader(txtArquivoTexto.Text)

                    'cria um documento PDF
                    Dim pdf As PdfDocument = New PdfDocument
                    'define o titulo
                    pdf.Info.Title = "Gerando PDF de arquivo texto"
                    'define uma pagina
                    Dim paginaPDF As PdfPage = pdf.AddPage
                    Dim graph As XGraphics = XGraphics.FromPdfPage(paginaPDF)
                    'define uma fonte
                    Dim font As XFont = New XFont("Trebuch", 14, XFontStyle.Regular)

                    'le o arquivo texto linha a linha
                    While True
                        linha = arquivoTexto.ReadLine()
                        If linha Is Nothing Then
                            Exit While
                        Else
                            'gera o texto no pdf
                            graph.DrawString(linha, font, XBrushes.Black, New XRect(10, yPonto, paginaPDF.Width.Point, paginaPDF.Height.Point), XStringFormats.TopLeft)
                            yPonto = yPonto + 20
                        End If
                    End While

                    'extrai o nome do arquivo sem a extensão e acrescenta .pdf
                    Dim arquivoPDF As String = Path.GetFileNameWithoutExtension(txtArquivoTexto.Text) + ".pdf"
                    'salva o pdf
                    pdf.Save(arquivoPDF)
                    'fecha o arquivo texto
                    arquivoTexto.Close()
                    arquivoTexto = Nothing
                    MessageBox.Show("Arquivo   [" + arquivoPDF + "]   gerado com sucesso.", "Alerta", MessageBoxButtons.OK, MessageBoxIcon.Information)
                    'exibe o arquivo texto criado
                    Process.Start(arquivoPDF)
                Else
                    MessageBox.Show("O arquivo/diretório de destino não existe...", "Alerta", MessageBoxButtons.OK, MessageBoxIcon.Information)
                End If
            Else
                MessageBox.Show("Informe o arquivo o texto...", "Alerta", MessageBoxButtons.OK, MessageBoxIcon.Information)
            End If
        Catch ex As Exception
            MessageBox.Show("Erro : " + ex.Message, "Erro", MessageBoxButtons.OK, MessageBoxIcon.Error)
        End Try
    End Sub

Quer migrar para o VB .NET ?

• Veja mais sistemas completos para a plataforma .NET no Super DVD .NET , confira...

• Curso Básico VB .NET - Vídeo Aulas

Quer aprender C# ??

• Chegou o Super DVD C# com exclusivo material de suporte e vídeo aulas com curso básico sobre C#.

• Curso C# Basico - Video Aulas

Quer aprender os conceitos da Programação Orientada a objetos ?

• Curso Fundamentos da Programação Orientada a Objetos com VB .NET

Quer aprender o gerar relatórios com o ReportViewer no VS 2013 ?

•  Curso - Gerando Relatórios com o ReportViewer no VS 2013 - Vídeo Aulas