A sua Loja Virtual - Encerrando suas compras e indo para o Caixa

Quando usuário encerrar as suas compras , ele é direcionado para a página que informa o valor total do pedido mais o frete que deverá ser pago para remessa via correio. No nosso exemplo o frete não esta sendo cobrado da região sudeste.(SP , RJ , MG , ES ) 

 

Para criar uma loja virtual usando ASP .NET acompanhe o curso no link : 

ASP .NET - Criando um site completo com carrinho de compras (Curso)

 

O usuário deverá informar os seguintes dados do pagador da fatura :

O arquivo caixa.asp irá gerar a tela abaixo , onde o usuário irá fornecer os dados e confirmar a sua compra. 

   

A seguir temos o código fonte do arquivo caixa.asp.

<%@ Language=VBScript %>
<%
Option Explicit

'Declara Variáveis
Dim conntemp
Dim SQL
Dim rsclientes
Dim ValorTotalPedido
Dim PesoTotal
Dim rsEstados
Dim rsProdutos
Dim rsFrete
Dim rsItens_Pedidos
Dim PesoProduto
Dim regiao


'Se o cliente ainda nao foi identificado chama a página de identificacao
 If ( Session("ClienteID") = 0 ) Then
   Response.Redirect "Identifica.asp?Tipo=NOVO"
End If

'-------------------------------------- 
'Abre conexão com o banco de dados
'--------------------------------------
 Sub Abre_ConexaoBD
  Set conntemp = Server.CreateObject("ADODB.Connection") 
  conntemp.Open Application("Conecta_bd")
End Sub

'--------------------------------------
'Fecha conexão com o banco de dados
'--------------------------------------
 Sub Fecha_ConexaoBD
  conntemp.Close 
  Set conntemp = Nothing
End Sub

Session("cad_nome") = Request.Form("nome")
Session("cad_endereco")= Request.Form("endereco")
Session("cad_estado")= Request.Form("estado")
Session("cad_cidade") = Request.Form("cidade")
Session("cad_cep")= Request.Form("cep")

Abre_ConexaoBD

pesoTotal = 0
SQL = "Select * from Itens_Pedidos where PedidoID =" & Session("PedidoID")
set rsItens_Pedidos = conntemp.Execute (SQL)

do while not rsItens_Pedidos.eof

SQL = "Select * from Produtos where ProdutoID = " & rsItens_Pedidos("ProdutoID")
set rsProdutos = conntemp.Execute (SQL)
pesoProduto = rsProdutos("Peso") * rsItens_Pedidos("Quantidade")
pesoTotal = pesoTotal + pesoProduto
rsProdutos.Close

rsItens_Pedidos.MoveNext

loop

Select Case Ucase(session("cad_estado"))
Case "RS", "SC", "PR"
  regiao = "Sul"
Case "RJ", "MG", "ES", "SP"
  regiao = "Sudeste"
Case "MS", "MT", "TO", "GO", "DF"
  regiao = "Centro-oeste"
Case "RO", "AC", "AP","PA","AM","RR"
  regiao = "Norte"
Case else
  regiao = "Nordeste"
End Select

SQL = "Select * From Frete Where Estado='" & regiao & "' And PesoMaximo >= " & Replace(FormatNumber(pesototal,2),",",".") & " And PesoMinimo <= " & Replace(FormatNumber(pesoTotal,2),",",".")
set rsFrete = conntemp.Execute (SQL)

Session("valor_frete") = rsFrete("Valor")
rsfrete.Close
Session("valorTotalPedido") = Session("totalgeral") + Session("valor_frete")
%>
<html>
<head>
<meta http-equiv="Content-Language" content="pt-br">
<meta http-equiv="Content-Type" content="text/html; charset=windows-1252">
<meta name="GENERATOR" content="Microsoft FrontPage 4.0">
<meta name="ProgId" content="FrontPage.Editor.Document">
<title>Caixa</title>
</head>
<body link="#008080" vlink="#008080" alink="#008080">
<table border="0" width="698">
<tr>
<TD bgcolor="#FFFFFF" width="689">
<p align="center"><b><font color="#008080" size="5" face="Verdana">JcmSoft
- A sua Loja Virtual</font></b>
</TD>
</tr>
<tr>
<TD align=middle bgColor=#008080 width="689">
<p align="center"><B><FONT color=#FFFFFF 
face=arial size=-2>Copyright JcmSoft. Todos os direitos reservados</FONT></B></p>
</TD>
</tr>
</table>
<hr>
<p><font face="Verdana" size="2"><b><font color="#008080">Valor do Frete
e do Pedido</font> </b></font><font face="Verdana" size="1">(Para a região
Sudeste - SP, RJ, MG, ES - o frete é grátis)</font></p>
<table border="1" width="729" height="46">
<tr>
<td width="113" align="center" bgcolor="#008080" height="16">
<p><font face="Arial" size="2" color="#FFFFFF"><b>Peso (em Kg)</b></font></p>
</td><td width="220" align="center" bgcolor="#008080" height="16">
<p><font face="Arial" size="2" color="#FFFFFF"><b>Valor do Frete (R$)</b></font></p>
</td><td width="374" align="center" bgcolor="#008080" height="16">
<p><font face="Arial" size="2" color="#FFFFFF"><b>Valor&nbsp;do Pedido (R$)</b></font></p>
</td>
</tr>
<tr><td width="113" align="center" height="18"><%=FormatNumber(pesoTotal,2)%>&nbsp;</td><td width="220" align="center" height="18"><%=FormatCurrency(Session("valor_Frete"))%>&nbsp;</td><td width="374" align="center" height="18"><%=FormatCurrency(Session("ValorTotalPedido"))%>&nbsp;</td>
</tr>
</table>

<form method="POST" action="encerra_compras.asp" name="caixa" onsubmit="return checa_dados()">
<p><font face="Verdana" size="2"><b><font color="#008080">Pagamento com
Cartão de Crédito</font> :</b></font></p>

<hr color="#008080">
<table border="0" width="100%" cellspacing="0" cellpadding="0">
<tr>
<td width="26%" align="right"><font color="#008080"><b>Cartão: </b></font> </td>
<td width="74%"><font color="#008080"><b><select size="1" name="cartao">
<option selected>--Selecione--</option>
<option>Visa</option>
<option>Master Card</option>
<option>American Express</option>
</select> </b></font> </td>
</tr>
<tr>
<td width="26%" align="right"><font color="#008080" face="Verdana" size="2"><b>Nome no
Cartão:</b></font></td>
<td width="74%"><input type="text" name="nomecartao" size="40"></td>
</tr>
<tr>
<td width="26%" align="right"><font color="#008080"><b>Número do Cartão: </b></font> </td>
<td width="74%"><font color="#008080"><b><input type="text" name="numerocartao" size="23"> </b></font> </td>
</tr>
<tr>
<td width="26%" align="right"><font color="#008080" face="Verdana" size="2"><b>Validade
do cartão:</b></font></td>
<td width="74%"><font face="Verdana" size="2"> <input type="text" name="validadecartao" size="10">
(MM/AAAA)</font></td>
</tr>
</table>
<hr color="#008080">
<%
conntemp.execute("Update Pedidos set valorfrete = " & replace(Formatnumber(Session("valorfrete"),2),",",".") & " where PedidoID = " & Session("PedidoID"))
fecha_ConexaoBD
%>
<table border="0" width="100%" cellspacing="0" cellpadding="0">
<tr>
<td width="50%">
<p align="center"><input type="submit" value="Confirma " name="B2"></td>
<td width="50%">
<p align="center"><a href="http://macorati/loja/comprar.asp"><img border="0" src="IMAGENS/retorna.gif"></a></td>
</tr>
</table>
<p>&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;</p>
</form>

</body>
</html>

<SCRIPT LANGUAGE="JavaScript">
<!--//
function checa_dados() 
{
if (document.caixa.cartao.selectedIndex == 0) {
  alert("Selecione o cartão de Crédito !");
  document.caixa.cartao.focus();
return false;
}

if (document.caixa.nomecartao.value.length == 0) {
  alert("Informe o seu nome no cartão de credito !");
  document.caixa.nomecartao.focus();
return false;
}

if (document.caixa.numerocartao.value.length == 0) {
  alert("Informe o numero do cartão de crédito !");
  document.caixa.numerocartao.focus();
return false;
}

if (document.caixa.numerocartao.value.length > 0) {
  if (IsCreditCard(document.caixa.selectedIndex,document.caixa.numerocartao.value) == false ) {
  alert("O numero do cartao de crédito é inválido !");
  document.caixa.numerocartao.focus()
return false;
}
}

if (document.caixa.validadecartao.value.length == 0) {
  alert("Informe a validade do cartão !");
  document.caixa.validadecartao.focus();
return false;
}

return true;
} 
//-->
</SCRIPT>


<SCRIPT LANGUAGE="VBScript">

Function IsCreditCard(ByRef asCardType, ByRef anCardNumber)

' Verifica a validade do cartao de credito

' Para testar voce pode usar os números a seguir:

' Visa: 430-00000-00000
' American Express: 372-00000-00000
' Mastercard: 521-00000-00000
' Discover: 620-00000-00000

Dim lsNumber          ' Credit card number stripped of all spaces, dashes, etc.
Dim lsChar              ' an individual character
Dim lnTotal              ' Sum of all calculations
Dim lnDigit              ' A digit  found within a credit card number
Dim lnPosition          ' identifies a character position in a string
Dim lnSum              ' Sum of calculations for a specific set

' O resultado padrão e False
IsCreditCard = False


  'Executa um laço atraves de cada caractere do número submetido
For lnPosition = 1 To Len(anCardNumber)

  ' Pega o caractere atual
  lsChar = Mid(anCardNumber, lnPosition, 1)

  'Se o caractere é um número , anexa-o ao nosso novo numero
  If IsNumeric(lsChar) Then lsNumber = lsNumber & lsChar

Next 

' ====
' O numero do cartao deve ter entre 13 a 16 digitos.
' ====

'  Se o tamanho do numero é menor que 13 , sai da rotina
If Len(lsNumber) < 13 Then Exit Function

  ' Se o tamanho do numero é maior que 16 sai da rotina
If Len(lsNumber) > 16 Then Exit Function

' ====
' O numero do cartao deve comecar com: 
' 4   para Visa Cards 
' 37 para American Express Cards 
' 5   para  MasterCards 
' 6   para Discover Cards 
' ====

  ' Dependendo do tipo do cartao executa uma ação
Select Case LCase(asCardType)

' VISA
Case "visa", "v" ,"1"

  'Se o primeiro digito não e 4 entao sai da função
If Not Left(lsNumber, 1) = "4" Then Exit Function

  ' American Express
 Case "american express", "americanexpress", "american", "ax", "a" , "3"

  ' Se os primeiros dois digitos sao diferente de 37 sai da função
If Not Left(lsNumber, 2) = "37" Then Exit Function

 ' Mastercard
 Case "mastercard", "master card", "master", "m" , "2"

  ' Se o primeiro digito não é 5 sai da função
If Not Left(lsNumber, 1) = "5" Then Exit Function

 ' Discover
 Case "discover", "discovercard", "discover card", "d"

' Se o primeiro digito não é 6 sai da função
If Not Left(lsNumber, 1) = "6" Then Exit Function

Case Else

End Select ' LCase(asCardType)

' ====
' Se o numero do cartao é menor que 16 digitos acrescenta zeros a esquerda para comecar com 16 digitos
' ====

While Not Len(lsNumber) = 16

' insere 0 ao inicio do numero
 lsNumber = "0" & lsNumber

Wend   

' ====
' multiplica cada digito do numero do cartao pelo digito correspondente da mascara e soma o resultado
' ====

'  percorre cada digito
For lnPosition = 1 To 16

lnDigit = Mid(lsNumber, lnPosition, 1)

' Determina se vamos multiplicar por:
' 1 (impar)
' 2 (par)
lnMultiplier = 1 + (lnPosition Mod 2)

' calcula a soma multiplicando o digito pelo multiplicador
 lnSum = lnDigit * lnMultiplier
If lnSum > 9 Then lnSum = lnSum - 9

' soma a soma com o total geral
lnTotal = lnTotal + lnSum

Next 

IsCreditCard = ((lnTotal Mod 10) = 0)

End Function ' IsCreditCard
</SCRIPT>
codigo fonte do arquivo caixa.asp

Vejamos as partes principais do código acima:

pesoTotal = 0
SQL = "Select * from Itens_Pedidos where PedidoID =" & Session("PedidoID")
set rsItens_Pedidos = conntemp.Execute (SQL)

do while not rsItens_Pedidos.eof

SQL = "Select * from Produtos where ProdutoID = " & rsItens_Pedidos("ProdutoID")
set rsProdutos = conntemp.Execute (SQL)
pesoProduto = rsProdutos("Peso") * rsItens_Pedidos("Quantidade")
pesoTotal = pesoTotal + pesoProduto
rsProdutos.Close

rsItens_Pedidos.MoveNext

loop
Select Case Ucase(session("cad_estado"))
Case "RS", "SC", "PR"
  regiao = "Sul"
Case "RJ", "MG", "ES", "SP"
  regiao = "Sudeste"
Case "MS", "MT", "TO", "GO", "DF"
  regiao = "Centro-oeste"
Case "RO", "AC", "AP","PA","AM","RR"
  regiao = "Norte"
Case else
  regiao = "Nordeste"
End Select

SQL = "Select * From Frete Where Estado='" & regiao & "' And PesoMaximo >= " & Replace(FormatNumber(pesototal,2),",",".") & " And PesoMinimo <= " & Replace(FormatNumber(pesoTotal,2),",",".")
set rsFrete = conntemp.Execute (SQL)

Session("valor_frete") = rsFrete("Valor")
rsfrete.Close
Session("valorTotalPedido") = Session("totalgeral") + Session("valor_frete")

Após Confirmar os dados informados , se tudo estiver correto ( a função checa_dados verifica se o valor para cada campo foi informado) , o arquivo encerra_compras.asp será executado e irá gerar a tela a seguir com o resumo do pedido contendo os dados do destinatário e do responsável pelo pagamento da fatura bem como um aviso informando quando o pedido será despachado.
A tela gerada pelo arquivo de script encerra_compras.asp

Além disso um e-mail é enviado para o cliente confirmando a transação . A função envia_mail() utiliza um componente de terceiros - o ASPMail - que deve estar instalado e configurado no servidor ( para máquinas locais usando o PWS . Se voce possuir o Windows NT pode usar o CDONTS). Voce pode fazer o download do componente e da documentação no site www.serverobjects.com . (É um shareware).  Você pode também usar outro componente, basta fazer os ajustes no código...

O código de como gerar o e-mail é exibido a seguir:

Dim msg
Dim Mail

Set Mail = Server.CreateObject("SMTPsvg.Mailer")

Mail.FromName = "JcmSoft - A sua loja Virtual"
Mail.RemoteHost = "mail.riopreto.com.br"     'nome do servidor SMTP
Mail.FromAddress = "macoratti@riopreto.com.br"    'remetente

Mail.AddRecipient Session("clienteNome"),Request.Cookies("cookie_EMail")    'destinatario

'Mail.Subject "Obrigado pela sua visita e pela sua compra ! "

msg = Session("ClienteNome") & vbcrlf
msg = msg & vbcrlf
msg = msg & " Seu pedido foi recebido com sucesso ! " & vbcrlf
msg = msg & " Dentro de 24 hs estaremos enviando o seu pedido " & vbcrlf
msg = msg & " Para o seguinte endereço " & vbcrlf
msg = msg & " --------------------------------------------------------------------" & vbcrlf
msg = msg & Session("cad_nome") & vbcrlf
msg = msg & Session("cad_endereco") & vbcrlf
msg = msg & Session("cad_cidade") & vbcrlf 
msg = msg & Session("cad_estado") & vbcrlf
msg = msg & Session("cad_cep") & vbcrlf 
msg = msg & " --------------------------------------------------------------------" & vbcrlf
msg = msg & " Valor do pedido mais o frete : " & formatcurrency(session("total_frete")) & vbcrlf
msg = msg & " Pagamento com cartao de credito : " & request.form("cartao") & vbcrlf
msg = msg & " Numero do cartao de credido : " & request.form("numerocartao") & vbcrlf
msg = msg & " Nome do titular do cartao de credito : " & request.form("nomecartao") & vbcrlf
msg = msg & " Validade do cartao de credito : " & request.form("validadecartao") & vbcrlf
msg = msg & " --------------------------------------------------------------------" & vbcrlf

Mail.BodyText = msg

on error resume next

if not Mail.SendMail then
  Response.Write " Ocorreu uma falha no envio do e-mail / "
  Response.Write " O componente de E-mail expira em : " & Mail.Expires & "<br>"
  Response.write Session("clienteNome") & " - "
  Response.write Request.Cookies("cookie_EMail") & "<p>"

  erro = true
else
    Response.Write " E-mail enviado com sucesso !<p>"
    erro = false 
end if

Criamos um objeto do tipo SMTPsvg.Mailer(Set Mail = Server.CreateObject("SMTPsvg.Mailer") e a seguir utilizamos as propriedades deste objeto. Descrevemos a seguir as principais propriedades :

Após enviar o e-mail a tabela de pedidos é atualizado com os dados do  pedido que acabou de ser concretizado. Abaixo o código que realiza a atualização . Usamos a instrução SQL UPDATE / SET.

sql = "UPDATE pedidos SET"
sql = sql & " CartaoCredito = '" & request.form("cartao") & "',"
sql = sql & " NumeroCartao = '" & request.form("numerocartao") & "',"
sql = sql & " TitularCartao = '" & request.form("nomecartao") & "',"
sql = sql & " ValidadeCartao = '" & request.form("validadecartao") & "',"
sql = sql & " ValorFrete = " & replace(Formatnumber(Session("valor_frete"),2),",",".") & ","
sql = sql & " ValorPedido = " & replace(Formatnumber(Session("totalgeral"),2),",",".") & ","
sql = sql & " NomeDestinatario = '" & session("cad_nome") & "',"
sql = sql & " EnderecoDestinatario = '" & session("cad_endereco") & "',"
sql = sql & " CidadeDestinatario = '" & session("cad_cidade") & "',"
sql = sql & " EstadoDestinatario = '" & session("cad_estado") & "',"
sql = sql & " CepDestinatario = '" & session("cad_cep") & "'," 
sql = sql & " Fechado = True" 
sql = sql & " WHERE PedidoID = " & Session("PedidoID")

conntemp.Execute sql

abaixo código completo do arquivo encerra_compras.asp :

<%@ Language=VBScript %>
<%
Option Explicit

'Declara Variáveis
Dim conntemp
Dim sql
Dim erro 

'Se o cliente ainda nao foi identificado chama a página de identificacao
If ( Session("ClienteID") = 0 ) Then
Response.Redirect "Identifica.asp?Tipo=NOVO"
End If

'-------------------------------------- 
'Abre conexão com o banco de dados
'--------------------------------------
Sub Abre_ConexaoBD
  Set conntemp = Server.CreateObject("ADODB.Connection") 
  conntemp.Open Application("Conecta_bd")
End Sub

'-------------------------------------------
'Envia e-mail ao cliente
'-------------------------------------------
Sub Envia_Email
'Declaração das Variáveis 
Dim msg
Dim Mail

Set Mail = Server.CreateObject("SMTPsvg.Mailer")

Mail.FromName = "JcmSoft - A sua loja Virtual"
Mail.RemoteHost = "mail.riopreto.com.br"     'nome do servidor SMTP
Mail.FromAddress = "macoratti@riopreto.com.br"    'remetente

Mail.AddRecipient Session("clienteNome"),Request.Cookies("cookie_EMail")    'destinatario

'Mail.Subject "Obrigado pela sua visita e pela sua compra ! "

msg = Session("ClienteNome") & vbcrlf
msg = msg & vbcrlf
msg = msg & " Seu pedido foi recebido com sucesso ! " & vbcrlf
msg = msg & " Dentro de 24 hs estaremos enviando o seu pedido " & vbcrlf
msg = msg & " Para o seguinte endereço " & vbcrlf
msg = msg & " --------------------------------------------------------------------" & vbcrlf
msg = msg & Session("cad_nome") & vbcrlf
msg = msg & Session("cad_endereco") & vbcrlf
msg = msg & Session("cad_cidade") & vbcrlf 
msg = msg & Session("cad_estado") & vbcrlf
msg = msg & Session("cad_cep") & vbcrlf 
msg = msg & " --------------------------------------------------------------------" & vbcrlf
msg = msg & " Valor do pedido mais o frete : " & formatcurrency(session("total_frete")) & vbcrlf
msg = msg & " Pagamento com cartao de credito : " & request.form("cartao") & vbcrlf
msg = msg & " Numero do cartao de credido : " & request.form("numerocartao") & vbcrlf
msg = msg & " Nome do titular do cartao de credito : " & request.form("nomecartao") & vbcrlf
msg = msg & " Validade do cartao de credito : " & request.form("validadecartao") & vbcrlf
msg = msg & " --------------------------------------------------------------------" & vbcrlf

Mail.BodyText = msg

on error resume next

if not Mail.SendMail then
  Response.Write " Ocorreu uma falha no envio do e-mail / "
  Response.Write " O componente de E-mail expira em : " & Mail.Expires & "<br>"
  Response.write Session("clienteNome") & " - "
  Response.write Request.Cookies("cookie_EMail") & "<p>"

  erro = true
else
    Response.Write " E-mail enviado com sucesso !<p>"
    erro = false 
end if

set Mail = nothing
on error goto 0
End Sub 

'--------------------------------------
'Fecha conexão com o banco de dados
'--------------------------------------
Sub Fecha_ConexaoBD
  conntemp.Close 
  Set conntemp = Nothing
End Sub

call Envia_Email()

Abre_ConexaoBD

sql = "UPDATE pedidos SET"
sql = sql & " CartaoCredito = '" & request.form("cartao") & "',"
sql = sql & " NumeroCartao = '" & request.form("numerocartao") & "',"
sql = sql & " TitularCartao = '" & request.form("nomecartao") & "',"
sql = sql & " ValidadeCartao = '" & request.form("validadecartao") & "',"
sql = sql & " ValorFrete = " & replace(Formatnumber(Session("valor_frete"),2),",",".") & ","
sql = sql & " ValorPedido = " & replace(Formatnumber(Session("totalgeral"),2),",",".") & ","
sql = sql & " NomeDestinatario = '" & session("cad_nome") & "',"
sql = sql & " EnderecoDestinatario = '" & session("cad_endereco") & "',"
sql = sql & " CidadeDestinatario = '" & session("cad_cidade") & "',"
sql = sql & " EstadoDestinatario = '" & session("cad_estado") & "',"
sql = sql & " CepDestinatario = '" & session("cad_cep") & "'," 
sql = sql & " Fechado = True" 
sql = sql & " WHERE PedidoID = " & Session("PedidoID")

conntemp.Execute sql

session("total_frete") = session("valor_frete") + session("totalgeral")

Fecha_ConexaoBD

%>
<!-- #Include file="ADOVBS.INC" -->
<html>
<head>
<meta http-equiv="Content-Language" content="pt-br">
<meta http-equiv="Content-Type" content="text/html; charset=windows-1252">
<meta name="GENERATOR" content="Microsoft FrontPage 4.0">
<meta name="ProgId" content="FrontPage.Editor.Document">
<title>Caixa</title>
</head>
<body link="#008080" vlink="#008080" alink="#008080">
<table border="0" width="698">
<tr>
<TD bgcolor="#FFFFFF" width="689">
<p align="center"><b><font color="#008080" size="5" face="Verdana">JcmSoft
- A sua Loja Virtual</font></b>
</TD>
</tr>
<tr>
<TD align=middle bgColor=#008080 width="689">
<p align="center"><B><FONT color=#FFFFFF 
face=arial size=-2>Copyright JcmSoft. Todos os direitos reservados</FONT></B></p>
</TD>
</tr>
<tr>
<TD align=middle bgColor=#FFFFFF width="689">
<p align="left" style="word-spacing: 0; margin-top: 0; margin-bottom: 0">
<b><font face="Verdana" color="#008080" size="3">Resumo do seu Pedido - <%=Session("ClienteNome")%></font></b>
</p>
<hr>
</TD>
</tr>
<tr>
<td width="689">
<table border="0" width="101%" cellspacing="0" cellpadding="0" bordercolordark="#000000" height="186">
<tr>
<td width="24%" align="left" height="19"><font face="Verdana" size="1">Número
do Pedido</font></td>
<td width="76%" colspan="5" height="19"><font face="Verdana" size="2"><%=Session("PedidoId")%></td>
</font></tr>
<tr>
<td width="24%" align="left" height="19"><font face="Verdana" size="1">Nome</font></td>
<td width="76%" colspan="5" height="19"><font face="Verdana" size="1"><%=session("cad_nome")%>&nbsp;</font></td>
</tr>
<tr>
<td width="24%" align="left" height="19"><font face="Verdana" size="1">Endereço</font></td>
<td width="76%" colspan="5" height="19"><font face="Verdana" size="1"><%=session("cad_endereco")%>&nbsp;</font></td>
</tr>
<tr>
<td width="24%" align="left" height="19"><font face="Verdana" size="1">Cep</font></td>
<td width="11%" height="19"><font face="Verdana" size="1"><%=session("cad_cep")%>&nbsp;</font></td>
<td width="8%" height="19">
<p align="left"><font face="Verdana" size="1">Cidade :</font></p>
</td>
<td width="42%" height="19"><font face="Verdana" size="1"><%=session("cad_cidade")%></font></td>
<td width="7%" height="19">
<p align="left"><font face="Verdana" size="1">UF:</font></p>
</td>
<td width="10%" height="19"><font face="Verdana" size="1"><%=session("cad_estado")%></font></td>
</tr>
<tr>
<td width="24%" align="left" height="19"><font face="Verdana" size="1">Valor do Pedido+frete</font></td>
<td width="76%" colspan="5" height="19"><font face="Verdana" size="1"><%=formatcurrency(session("total_frete"))%>&nbsp;</font></td>
</tr>
<tr>
<td width="100%" align="left" height="16" colspan="6">
<hr>
</td>
</tr>
<tr>
<td width="24%" align="left" height="19"><font face="Verdana" size="1">Cartão</font></td>
<td width="76%" colspan="5" height="19"><font face="Verdana" size="1"><%=request.form("cartao")%>&nbsp;</font></td>
</tr>
<tr>
<td width="24%" align="left" height="19"><font face="Verdana" size="1">Número</font></td>
<td width="76%" colspan="5" height="19"><font face="Verdana" size="1"><%=request.form("numerocartao")%>&nbsp;</font></td>
</tr>
<tr>
<td width="24%" align="left" height="19"><font face="Verdana" size="1">Titular</font></td>
<td width="76%" colspan="5" height="19"><font face="Verdana" size="1"><%=request.form("nomecartao")%>&nbsp;</font></td>
</tr>
<tr>
<td width="24%" align="left" height="19"><font face="Verdana" size="1">Validade</font></td>
<td width="76%" colspan="5" height="19"><font face="Verdana" size="1"><%=request.form("validadecartao")%>&nbsp;</font></td>
</tr>
<tr>
<td width="100%" align="left" height="19" colspan="6">
<hr>
</td>
</tr>
</table>
</td> </tr>
<tr>
<td width="689">
<p align="center"><b><font face="Verdana" color="#008080" size="3">Seu pedido foi concluído
com sucesso.</font></b></td> </tr>
<tr>
<td width="689">
<p align="center"><b><font face="Verdana" color="#008080" size="3">Dentro de 24 horas
estará sendo enviado conforme sua solicitação.<br>
<% if erro = false then
Response.Write "Um e-mail com o resumo do pedido foi enviado para -> " & Request.Cookies("cookie_EMail")
end if
%> 
</font></b></td> </tr>
<tr>
<td width="689">
<p align="center"><b><font face="Verdana" color="#008080" size="3">Obrigado.</font></b></td> </tr>
<tr>
<td width="689">
<hr>
</td> </tr>
<tr>
<td width="689">
<p align="center"><a href="http://macorati/loja/index.htm"><img border="0" src="IMAGENS/retorna.gif"></a></td> </tr>
</table>

</body>
</html>
arquivo encerra_compras.asp

Aqui encerramos a primeira parte da loja Virtual .

A segunda parte refere-se a atualização dos dados referentes aos pedidos , valores e demais tabelas. Iremos mostrar como fazer a atualização do estoque e das demais tabelas remotamente.Veja os tópicos que serão abordados:

  1. Como fazer uma conexão com verificação de identificação do usuário : nome e senha
  2. Atualizando a tabela de produtos : Incluir , Excluir e atualizar produtos.
  3. Atualizar a tabela de fretes : Incluir , Alterar e Excluir dados referentes aos fretes
  4. Outras cositas mas...

Aguarde...

 Parte Anterior Próxima parte

Veja os Destaques e novidades do SUPER DVD Visual Basic (sempre atualizado) : clique e confira !

Quer migrar para o VB .NET ?

Quer aprender C# ??

Quer aprender os conceitos da Programação Orientada a objetos ?

Quer aprender o gerar relatórios com o ReportViewer no VS 2013 ?

Quer aprender a criar aplicações Web Dinâmicas usando a ASP .NET MVC 5 ?

 

  Gostou ?   Compartilhe no Facebook   Compartilhe no Twitter

 

Referências:

José Carlos Macoratti