Thread, ou linha de execução

Uma linha de execução permite que o usuário de programa, por exemplo, utilize uma funcionalidade do ambiente enquanto outras linhas de execução realizam outros cálculos e operações.

Em hardwares equipados com uma única CPU, cada linha de execução(Thread) é processada de forma aparentemente simultânea, pois a mudança entre uma linha e outra é feita de forma tão rápida que para o usuário isso está acontecendo paralelamente. Em hardwares com múltiplas CPUs ou multi-cores as linhas de execução(Threads) podem ser realizadas realmente de forma simultânea;
(wikipédia)

Um soquete pode ser usado em ligações de redes de computadores

É também uma abstração computacional que mapeia diretamente a uma porta de transporte (TCP ou UDP) e mais um endereço de rede. Com esse conceito é possível identificar unicamente um aplicativo ou servidor na rede de comunicação IP.(wikipédia)

A .NET Framework fornece uma poderosa classe HashTable.

Uma HasTable é uma coleção onde os elementos possuem chave/valor , e onde cada elemento é indexado usando uma chave alfanumérica.

Ao trabalhar com a classe Hastable tenha em mente que a ordenação dos elementos na coleção é independente da ordem na qual ele entrou na tabela . A classe emprega seu próprio algoritmo hash para ordenar de forma eficiente os pares chave/valor da coleção.

Imports System.Net
Imports System.Text

Module Module1

    Dim listaClientes As New Hashtable

    Sub Main()

        Dim enderecoLocal As IPAddress = IPAddress.Parse("127.0.0.1")
        Dim serverSocket As New TcpListener(enderecoLocal, 8888)

        Dim clientSocket As TcpClient = Nothing
        Dim contador As Integer

        serverSocket.Start()
        Mensagem("Servidor Chat Iniciado ....")
        contador = 0

        While (True)
            contador += 1
            clientSocket = serverSocket.AcceptTcpClient()

            Dim bytesFrom(10024) As Byte
            Dim dadosDoCliente As String

            Dim networkStream As NetworkStream = clientSocket.GetStream()
            networkStream.Read(bytesFrom, 0, CInt(clientSocket.ReceiveBufferSize))
            dadosDoCliente = Encoding.ASCII.GetString(bytesFrom)
            dadosDoCliente = dadosDoCliente.Substring(0, dadosDoCliente.IndexOf("$"))

            listaClientes(dadosDoCliente) = clientSocket

            broadcast(dadosDoCliente + " Entrou ", dadosDoCliente, False)

            Mensagem(dadosDoCliente + " Entrou na Sala ")
            Dim cliente As New tratarCliente
            cliente.iniciaCliente(clientSocket, dadosDoCliente, listaClientes)
        End While

        clientSocket.Close()
        serverSocket.Stop()
        Mensagem("sair")
        Console.ReadLine()
    End Sub

    Sub Mensagem(ByVal texto As String)
        texto.Trim()
        Console.WriteLine(" >> " + texto)
    End Sub

    Private Sub broadcast(ByVal Mensagem As String, ByVal nomeUsuario As String, ByVal flag As Boolean)

        Dim Item As DictionaryEntry

        For Each Item In listaClientes
            Dim broadcastSocket As TcpClient
            broadcastSocket = CType(Item.Value, TcpClient)
            Try
                Dim broadcastStream As NetworkStream = broadcastSocket.GetStream()
                Dim broadcastBytes As [Byte]()

                If flag = True Then
                    broadcastBytes = Encoding.ASCII.GetBytes(nomeUsuario + " diz : " + Mensagem)
                Else
                    broadcastBytes = Encoding.ASCII.GetBytes(Mensagem)
                End If

                broadcastStream.Write(broadcastBytes, 0, broadcastBytes.Length)
                broadcastStream.Flush()
            Catch ex As Exception
                MsgBox(ex.Message)
            End Try
        Next
    End Sub

    Public Class tratarCliente
        Dim clientSocket As TcpClient
        Dim clNo As String
        Dim listaClientes As Hashtable

        Public Sub iniciaCliente(ByVal inClientSocket As TcpClient, ByVal clineNo As String, ByVal cList As Hashtable)

            Me.clientSocket = inClientSocket
            Me.clNo = clineNo
            Me.listaClientes = cList

            Dim ctThread As Threading.Thread = New Threading.Thread(AddressOf doChat)
            ctThread.Start()
        End Sub

        Private Sub doChat()
            Dim contadorRequisicao As Integer
            Dim bytesFrom(10024) As Byte
            Dim dadosDoCliente As String
            Dim rContador As String
            contadorRequisicao = 0

            While (True)
                Try
                    contadorRequisicao = contadorRequisicao + 1

                    Dim networkStream As NetworkStream = clientSocket.GetStream()

                    networkStream.Read(bytesFrom, 0, CInt(clientSocket.ReceiveBufferSize))
                    dadosDoCliente = System.Text.Encoding.ASCII.GetString(bytesFrom)
                    dadosDoCliente = dadosDoCliente.Substring(0, dadosDoCliente.IndexOf("$"))

                    Mensagem("Cliente - " + clNo + " : " + dadosDoCliente)

                    rContador = Convert.ToString(contadorRequisicao)
                    broadcast(dadosDoCliente, clNo, True)

                Catch ex As Exception
                    MsgBox(ex.ToString)
                End Try
            End While
        End Sub

    End Class
End Module

A classe TcpListner é usada para escuta de conexões de clientes de rede TCP.

A classe TcpListener fornece métodos simples que escutam e aceitam solicitações de conexão de entrada no mode de bloqueio síncrono. Você pode usar um TcpClient ou um Socket para se conectar com um TcpListener.

Use o método Start para começar escutar solicitações de conexão de entrada. Ele irá enfileirar as requisições até você chamar o método Stop ou até atingir o máximo de conexões.(MaxConnections).

Você pode usar  tanto AcceptSocket como AcceptTcpClient para receber uma  requisição de conexão de entrada e colocá-la na fila.

Se você quiser evitar o bloqueio, você pode usar o método Pending primeiro, para determinar se as solicitações de conexão estão disponíveis na fila.

A classe TcpClient fornece conexões de cliente de serviços de rede TCP.

A classe TcpClient fornece métodos simples para conectar-se, enviar e de receber um de fluxo de dados em uma rede no modo síncrono de bloqueio.

A fim de da classe TcpClient se conectar e trocar dados, um TcpListener ou Socket criado com o ProtocolType TCP  deve estar escutando para solicitações de conexão de entrada. Você pode conectar-se com este Listner em uma das seguintes formas:

• Criar um TcpClient  e chamar um dos três métodos Connect disponíveis;
• Criar Um TcpClient usando o nome de host e número da porta do host remoto. Esse construtor irá automaticamente tentar uma conexão.

Imports System.Net.Sockets
Imports System.Text

Public Class Form1

    Dim clientSocket As New TcpClient()
    Dim serverStream As NetworkStream
    Dim lerDados As String

    Private Sub btnConectar_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnConectar.Click

        lerDados = "Conetado como Servidor ..."
        Mensagem()

        Try
            clientSocket.Connect("127.0.0.1", 8888)
            serverStream = clientSocket.GetStream()

            Dim outStream As Byte() = Encoding.ASCII.GetBytes(txtNome.Text + "$")
            serverStream.Write(outStream, 0, outStream.Length)
            serverStream.Flush()

            'cria uma nova thread para enviar mensagens
            Dim ctThread As Threading.Thread = New Threading.Thread(AddressOf getMensagem)
            ctThread.Start()
        Catch ex As Exception
            MsgBox(ex.Message)
        End Try
    End Sub

    Private Sub Mensagem()

        If Me.InvokeRequired Then
            Me.Invoke(New MethodInvoker(AddressOf Mensagem))
        Else
            txtDados.Text = txtDados.Text + Environment.NewLine + " >> " + lerDados
        End If

    End Sub

    Private Sub btnEnviarMensagem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnEnviarMensagem.Click

        Try
            Dim outStream As Byte() = Encoding.ASCII.GetBytes(txtMensagem.Text + "$")
            serverStream.Write(outStream, 0, outStream.Length)
            serverStream.Flush()
        Catch ex As Exception
            MsgBox(ex.Message)
        End Try

    End Sub

    Private Sub getMensagem()
        'loop infinito
        While (True)
            Try
                serverStream = clientSocket.GetStream()
                Dim buffSize As Integer
                Dim inStream(10024) As Byte
                buffSize = clientSocket.ReceiveBufferSize
                serverStream.Read(inStream, 0, buffSize)

                Dim dadosRetornados As String = Encoding.ASCII.GetString(inStream)
                lerDados = "" + dadosRetornados
                Mensagem()
            Catch ex As Exception
                MsgBox(ex.Message)
                Exit Sub
            End Try
        End While
    End Sub

End Class