Dim conn As New ADODB.Connection
-----------------------------------------------------------------------------------------------------
Public Sub ListaClientes()
Dim rstClientes As New ADODB.Recordset

'limpa o cabealho
ListViewClientes.ColumnHeaders.Clear
ListViewClientes.ListItems.Clear

'define a conexo e abre o Recordset com os dados da tabela Clientes
With rstClientes
 .CursorLocation = adUseClient
 .CursorType = adOpenKeyset
 .LockType = adLockOptimistic
 .CacheSize = 50
 .Source = "Select CdigodoCliente,NomedaEmpresa ,NomedoContato,CargodoContato from Clientes"
 .ActiveConnection = conn
 .Open
End With

'Cria o cabealho do controle ListView
ListViewClientes.ColumnHeaders.Add , , "Cdigo", 903
ListViewClientes.ColumnHeaders.Add , , "Nome da Empresa", 2300, lvwColumnLeft
ListViewClientes.ColumnHeaders.Add , , "Nome do Contato", 2300, lvwColumnLeft
ListViewClientes.ColumnHeaders.Add , , "Cargo do Contato", 2300, lvwColumnLeft

'Preenche o controle listview com os dados da tabela
Dim i As Integer
For i = 0 To rstClientes.RecordCount - 1
  Set LIClientesID = ListViewClientes.ListItems.Add(, rstClientes(0), rstClientes(0))
  If Not IsNull(rstClientes(0)) Then
     LIClientesID.SubItems(1) = rstClientes(1) 'nome da empresa
     LIClientesID.SubItems(2) = rstClientes(2) 'nome do contato
     LIClientesID.SubItems(3) = rstClientes(3) 'cargo do contato
End If
rstClientes.MoveNext
Next i

'fecha o recordset e libera a varivel
rstClientes.Close
Set rstClientes = Nothing
End Sub
-----------------------------------------------------------------------------------------------------
Private Sub Command1_Click()
   Call PrintListView(ListViewClientes, 10)
End Sub
-----------------------------------------------------------------------------------------------------
Private Sub Form_Load()
 conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:\teste\Northwind.mdb;"
 ListaClientes
End Sub
-----------------------------------------------------------------------------------------------------
Public Sub PrintListView(LV As ListView, Lines%)
Dim i%, LVWidth%, NewTab%, j%
Dim itmX As ListItem
Dim ContaLinha%
  
  LVWidth = 0
  For i = 1 To LV.ColumnHeaders.Count
     LVWidth = LVWidth + LV.ColumnHeaders(i).Width
  Next
  NewTab = 0
   'imprime o cabealho
  For i = 1 To LV.ColumnHeaders.Count
      NewTab = NewTab + CInt(LV.ColumnHeaders(i).Width * Printer.ScaleWidth / LVWidth)
      Printer.Print LV.ColumnHeaders(i).Text;
      Printer.CurrentX = NewTab
  Next
  'imprime uma linha de separao
  Printer.Print
  imprime_linha
  Printer.Print
  'se o numero de linhas do ListView for menor que o de linhas a
  'a imprimir ento imprime o contedo total de Listview
  If Lines < LV.ListItems.Count And Lines <> 0 Then
       ContaLinha = Lines
   Else
       ContaLinha = LV.ListItems.Count
   End If
  'imprime os itens e subitens
  For i = 1 To ContaLinha
       NewTab = 0
       Set itmX = LV.ListItems(i)
       Printer.Print itmX.Text;
       For j = 1 To LV.ColumnHeaders.Count - 1
             NewTab = NewTab + CInt(LV.ColumnHeaders(j).Width * Printer.ScaleWidth / LVWidth)
             Printer.CurrentX = NewTab
             Printer.Print itmX.SubItems(j);
       Next
       Printer.Print
  Next
  'envia os dados para impressora
  Printer.EndDoc
End Sub
-----------------------------------------------------------------------------------------------------
Private Sub imprime_linha()
 Dim linha As String
 linha = "-"
 
 Printer.CurrentX = 0
 While Printer.CurrentX + Printer.TextWidth(linha) <= Printer.ScaleWidth
    Printer.Print linha;
 Wend
 
End Sub

